mirror of
https://github.com/VCMP-SqMod/SqMod.git
synced 2025-06-24 11:07:11 +02:00
bin
module
vendor
CPR
ConcurrentQueue
Fmt
MaxmindDB
POCO
ApacheConnector
CppParser
CppUnit
Crypto
Data
Encodings
Foundation
JSON
JWT
MongoDB
Net
NetSSL_OpenSSL
NetSSL_Win
PDF
PageCompiler
PocoDoc
ProGen
Redis
SevenZip
Util
XML
Zip
appveyor
build
cmake
V313
V33
V39
FindEXPAT.cmake
CXX1x.cmake
DefinePlatformSpecifc.cmake
ExecuteOnAndroid.cmake
FindAPR.cmake
FindAPRUTIL.cmake
FindApache2.cmake
FindMySQL.cmake
FindODBC.cmake
FindPCRE.cmake
FindPostgreSQL.cmake
PocoConfig.cmake.in
PocoConfigVersion.cmake.in
PocoMacros.cmake
README
UseEmbeddedOpenSSL.cmake
cmake_uninstall.cmake.in
test_compiler.cpp
contrib
doc
packaging
patches
release
travis
.gitattributes
.gitignore
.gitmodules
.travis.yml
CHANGELOG
CMakeLists.txt
CODE_OF_CONDUCT.md
CONTRIBUTING.md
CONTRIBUTORS
LICENSE
Makefile
NEWS
README
README.md
VERSION
appveyor.yml
build_cmake.cmd
build_cmake.sh
build_vs140.cmd
build_vs150.cmd
build_vs160.cmd
buildwin.cmd
buildwin.ps1
components
configure
cppignore.lnx
cppignore.win
env.bat
env.sh
libversion
SimpleIni
Squirrel
TinyDir
CMakeLists.txt
.gitignore
.gitmodules
CMakeLists.txt
LICENSE
README.md
4a6bfc086c
Switched to POCO library for unified platform/library interface. Deprecated the external module API. It was creating more problems than solving. Removed most built-in libraries in favor of system libraries for easier maintenance. Cleaned and secured code with help from static analyzers.
80 lines
2.4 KiB
CMake
80 lines
2.4 KiB
CMake
# Distributed under the OSI-approved BSD 3-Clause License. See accompanying
|
|
# file Copyright.txt or https://cmake.org/licensing for details.
|
|
|
|
#.rst:
|
|
# FindEXPAT
|
|
# ---------
|
|
#
|
|
# Find the native Expat headers and library.
|
|
#
|
|
# Imported Targets
|
|
# ^^^^^^^^^^^^^^^^
|
|
#
|
|
# This module defines the following :prop_tgt:`IMPORTED` targets:
|
|
#
|
|
# ``EXPAT::EXPAT``
|
|
# The Expat ``expat`` library, if found.
|
|
#
|
|
# Result Variables
|
|
# ^^^^^^^^^^^^^^^^
|
|
#
|
|
# This module will set the following variables in your project:
|
|
#
|
|
# ``EXPAT_INCLUDE_DIRS``
|
|
# where to find expat.h, etc.
|
|
# ``EXPAT_LIBRARIES``
|
|
# the libraries to link against to use Expat.
|
|
# ``EXPAT_FOUND``
|
|
# true if the Expat headers and libraries were found.
|
|
#
|
|
|
|
find_package(PkgConfig QUIET)
|
|
|
|
pkg_check_modules(PC_EXPAT QUIET expat)
|
|
|
|
# Look for the header file.
|
|
find_path(EXPAT_INCLUDE_DIR NAMES expat.h HINTS ${PC_EXPAT_INCLUDE_DIRS})
|
|
|
|
# Look for the library.
|
|
find_library(EXPAT_LIBRARY NAMES expat libexpat HINTS ${PC_EXPAT_LIBRARY_DIRS})
|
|
|
|
if (EXPAT_INCLUDE_DIR AND EXISTS "${EXPAT_INCLUDE_DIR}/expat.h")
|
|
file(STRINGS "${EXPAT_INCLUDE_DIR}/expat.h" expat_version_str
|
|
REGEX "^#[\t ]*define[\t ]+XML_(MAJOR|MINOR|MICRO)_VERSION[\t ]+[0-9]+$")
|
|
|
|
unset(EXPAT_VERSION_STRING)
|
|
foreach(VPART MAJOR MINOR MICRO)
|
|
foreach(VLINE ${expat_version_str})
|
|
if(VLINE MATCHES "^#[\t ]*define[\t ]+XML_${VPART}_VERSION[\t ]+([0-9]+)$")
|
|
set(EXPAT_VERSION_PART "${CMAKE_MATCH_1}")
|
|
if(EXPAT_VERSION_STRING)
|
|
string(APPEND EXPAT_VERSION_STRING ".${EXPAT_VERSION_PART}")
|
|
else()
|
|
set(EXPAT_VERSION_STRING "${EXPAT_VERSION_PART}")
|
|
endif()
|
|
endif()
|
|
endforeach()
|
|
endforeach()
|
|
endif ()
|
|
|
|
include(FindPackageHandleStandardArgs)
|
|
FIND_PACKAGE_HANDLE_STANDARD_ARGS(EXPAT
|
|
REQUIRED_VARS EXPAT_LIBRARY EXPAT_INCLUDE_DIR
|
|
VERSION_VAR EXPAT_VERSION_STRING)
|
|
|
|
# Copy the results to the output variables and target.
|
|
if(EXPAT_FOUND)
|
|
set(EXPAT_LIBRARIES ${EXPAT_LIBRARY})
|
|
set(EXPAT_INCLUDE_DIRS ${EXPAT_INCLUDE_DIR})
|
|
|
|
if(NOT TARGET EXPAT::EXPAT)
|
|
add_library(EXPAT::EXPAT UNKNOWN IMPORTED)
|
|
set_target_properties(EXPAT::EXPAT PROPERTIES
|
|
IMPORTED_LINK_INTERFACE_LANGUAGES "C"
|
|
IMPORTED_LOCATION "${EXPAT_LIBRARY}"
|
|
INTERFACE_INCLUDE_DIRECTORIES "${EXPAT_INCLUDE_DIRS}")
|
|
endif()
|
|
endif()
|
|
|
|
mark_as_advanced(EXPAT_INCLUDE_DIR EXPAT_LIBRARY)
|